Guten Tag,
ich habe hunderte von doc-Dateien mit ein und demselben Passwort verschlüsselt und möchte nun
(im Stapel) bei allen Dateien das (mir natürlich bekannte) Passwort entfernen. Geht das überhaupt?
Vielen Dank für eure Bemühungen im Voraus.
Hallo Admin49,
ich habe hunderte von doc-Dateien mit ein und demselben
Passwort verschlüsselt und möchte nun
(im Stapel) bei allen Dateien das (mir natürlich bekannte)
Passwort entfernen. Geht das überhaupt?
das folgende Makro ermöglicht die Bearbeitung aller Dateien eines Verzeichnisses in einem Rutsch. Da die Dateien mit aktuellem Datum gespeichert werden ggf. vorher in einem anderen Verzeichnis Sicherheitskopien der geschützten Dateien erstellen.
Gruß
Franz
'Erstellt unter Word 2007
Sub RemovePassword()
'
Dim strPassword As String
Dim varVerzeichnis, strDatei As String, wdDoc As Document
With Application.FileDialog(msoFileDialogFolderPicker)
If .Show = -1 Then
strPassword = VBA.InputBox(Prompt:="Bitte das Kennwort für die Dateien eingeben", \_
Title:="Kennwort in Dokumenten entfernen", \_
Default:="Test")
If strPassword = "" Then GoTo Ende
Application.ScreenUpdating = False
varVerzeichnis = .SelectedItems(1)
strDatei = Dir(varVerzeichnis & Application.PathSeparator & "Dok\*.doc")
Do Until strDatei = ""
If LCase(strDatei) = LCase(ThisDocument.Name) Then
'do nothing
Else
Set wdDoc = Documents.Open(FileName:=varVerzeichnis \_
& Application.PathSeparator & strDatei, PasswordDocument:=strPassword, \_
WritePasswordDocument:=strPassword)
With wdDoc
.ReadOnlyRecommended = False
.Password = ""
.WritePassword = ""
End With
wdDoc.SaveAs FileName:=varVerzeichnis \_
& Application.PathSeparator & strDatei, Password:="", WritePassword:=""
wdDoc.Close savechanges:=False
End If
strDatei = Dir
Loop
Application.ScreenUpdating = True
End If
End With
MsgBox "Fertig"
Ende:
Set wdDoc = Nothing
End Sub