Dringend gesucht: Zelleninhalt teilen (mehr als 2x

Marylou · 3. September 2008 um 12:02

Hallo,

leider komme ich nicht weiter.

Folgende Sachlage:

Ich habe eine Zelle in der 4 Daten zusammengefasst sind: also
Zelle C1:
Telefon: 0241 / 0000 Fax: 0241 / 0001 E-Mail: [email protected] Web: www.0000.de

Dieser Inhalt soll in 4 separate Zellen aufgeteilt werden. (Separat Telefon + Nummer, dann Fax usw)

Folgende Formel habe ich benutzt:
=LINKS(C1;SUCHEN("Fax: ";C1)-1)
Das klappt dann bis zum Telefon und danach gehts nicht weiter, egal ob ich statt Fax dann Email eingebe aus -1 -2 mache oder aus Links - Rechts.

Wo ist mein Denkfehler?

Tausend Dank für Eure Hilfe.

Marie

Paradigma · 3. September 2008 um 12:16

Hallo,

Folgende Formel habe ich benutzt:
=LINKS(C1;SUCHEN("Fax: ";C1)-1)
Das klappt dann bis zum Telefon und danach gehts nicht weiter,
egal ob ich statt Fax dann Email eingebe aus -1 -2 mache oder
aus Links - Rechts.

Keine Ahnung, Du hast uns ja Deinen Ansatz für die Formel nicht verraten. Grundsätzlich sollze aber die Textformel TEIL weiter helfen…

Gruß HW
Hans W. HOfmann

Marylou · 3. September 2008 um 12:23

Hallo Hans,

vielen Dank für Ihre Antwort.
Die Textformel TEIL hilft leider nicht weiter.

Okay, wenn ich keine Formel genannt hätte - wie wäre denn dann Vorschlag/Ansatz/Formel?

Lieben Dank
Marie

[Bei dieser Antwort wurde das Vollzitat nachträglich automatisiert entfernt]

Reinhard_fb8cb7 · 3. September 2008 um 12:26

Ich habe eine Zelle in der 4 Daten zusammengefasst sind: also
Zelle C1:
Telefon: 0241 / 0000 Fax: 0241 / 0001 E-Mail: [email protected]
Web: www.0000.de

Dieser Inhalt soll in 4 separate Zellen aufgeteilt werden.

Hi Marie,

in C2 steht das Gleiche wie in C1:

Tabellenblatt: [Mappe3]!Tabelle1
 │ D │ E │ F │ G │
──┼───────────────────────┼───────────────────┼──────────────────────────┼──────────────────┤
1 │ Telefon: 0241 / 0000 │ Fax: 0241 / 0001 │ E-Mail: [email protected] │ Web: www.0000.de │
──┼───────────────────────┼───────────────────┼──────────────────────────┼──────────────────┤
2 │ 0241 / 0000 │ 0241 / 0001 │ [email protected] │ www.0000.de │
──┴───────────────────────┴───────────────────┴──────────────────────────┴──────────────────┘
Benutzte Formeln:
D1: =LINKS(C1;FINDEN("Fax";C1)-1)
D2: =TEIL(C2;9;FINDEN("Fax";C2)-9)
E1: =TEIL(C1;FINDEN("Fax";C1);FINDEN("E-Mail";C1)-FINDEN("Fax";C1))
E2: =TEIL(C2;FINDEN("Fax";C2)+5;FINDEN("E-Mail";C2)-FINDEN("Fax";C2)-5)
F1: =TEIL(C1;FINDEN("E-Mail";C1);FINDEN("Web";C1)-FINDEN("E-Mail";C1))
F2: =TEIL(C2;FINDEN("E-Mail";C2)+8;FINDEN("Web";C2)-FINDEN("E-Mail";C2)-8)
G1: =TEIL(C1;FINDEN("Web";C1);LÄNGE(C1)-FINDEN("Web";C1)+1)
G2: =TEIL(C2;FINDEN("Web";C2)+5;LÄNGE(C2)-FINDEN("Web";C2)-4)

D1:G2
haben das Zahlenformat: Standard

Tabellendarstellung erreicht mit dem Code in FAQ:2363

Gruß
Reinhard

Marylou · 3. September 2008 um 12:46

C2)-4)

D1:G2
haben das Zahlenformat: Standard

Tabellendarstellung erreicht mit dem Code in FAQ:2363

Gruß
Reinhard

Hallo Reinhard,

wirklich sensationell und tausend Dank für die schnelle Antwort. Es hat super geklappt!!! Lieben Dank!

Darf ich noch so eine ähnliche Frage stellen?

In der Zelle steht eine Straße, Nummer, PLZ, Ort
Adalbertsteinweg 34 52070 Aachen
dies müsste in 2 Zellen geteilt werden (Straße + Nr und PLZ + Ort)
Gibts dafür auch eine Lösung!

Liebe Grüße
Marie

Reinhard_fb8cb7 · 3. September 2008 um 12:56

In der Zelle steht eine Straße, Nummer, PLZ, Ort
Adalbertsteinweg 34 52070 Aachen
dies müsste in 2 Zellen geteilt werden (Straße + Nr und PLZ +
Ort)

Hi Marie,

schau mal zu Daten–Text in Spalten, als Trennzeichen das Lerzeichen nehmen, oder so z.B.

Tabellenblatt: [Mappe3]!Tabelle1
 │ A │ B │ C │
──┼──────────────────────────────────┼─────────────────────┼──────────────┤
3 │ Adalbertsteinweg 34 52070 Aachen │ Adalbertsteinweg 34 │ 52070 Aachen │
──┴──────────────────────────────────┴─────────────────────┴──────────────┘
Benutzte Formeln:
B3: =LINKS(A3;FINDEN(" ";A3;FINDEN(" ";A3)+1)-1)
C3: =WECHSELN(A3;B3&" ";"")

A3:C3
haben das Zahlenformat: Standard

Tabellendarstellung erreicht mit dem Code in FAQ:2363

Gruß
Reinhard

Marylou · 3. September 2008 um 13:03

Also Reinhard, ich komme aus dem Staunen nicht mehr raus und bin wirklich sehr dankbar, für die schnelle & gute Antwort.

Auch das hat geklappt, außer bei einigen, woran liegt das? Vielleicht weil ein Leerzeichen zuviel in der Ausgangszelle ist?

Adalbertsteinweg 34 52070 Aachen
Freunder Landstr. 54 52078 Aachen
Ulmer Str. 142 73431 Aalen
Josef-Wurzler-Straße 7 77855 Achern

Bei einigen ging die Hausnummer mit zur PLZ.

LIeben Gruß
Marie

Marylou · 3. September 2008 um 13:05

Okay hab die Antwort.
zwischen es immer ein Leerzeichen bei Werner_Straße_43
In Deiner Formel war es: WernerStraße_43

Kann man dies in eine Formel integrieren um beide Varianten abzudecken?

Danke, danke

Marie

Reinhard_fb8cb7 · 3. September 2008 um 13:37

Auch das hat geklappt, außer bei einigen, woran liegt das?
Vielleicht weil ein Leerzeichen zuviel in der Ausgangszelle
ist?

Adalbertsteinweg 34 52070 Aachen
Freunder Landstr. 54 52078 Aachen
Ulmer Str. 142 73431 Aalen
Josef-Wurzler-Straße 7 77855 Achern

Hi Marie,

dann so:

Tabellenblatt: [Mappe3]!Tabelle1
 │ A │ B │ C │
──┼─────────────────────────────────────┼────────────────────────┼──────────────┤
4 │ Adalbertsteinweg 34 52070 Aachen │ Adalbertsteinweg 34 │ 52070 Aachen │
──┼─────────────────────────────────────┼────────────────────────┼──────────────┤
5 │ Freunder Landstr. 54 52078 Aachen │ Freunder Landstr. 54 │ 52078 Aachen │
──┼─────────────────────────────────────┼────────────────────────┼──────────────┤
6 │ Ulmer Str. 142 73431 Aalen │ Ulmer Str. 142 │ 73431 Aalen │
──┼─────────────────────────────────────┼────────────────────────┼──────────────┤
7 │ Josef-Wurzler-Straße 7 77855 Achern │ Josef-Wurzler-Straße 7 │ 77855 Achern │
──┴─────────────────────────────────────┴────────────────────────┴──────────────┘
Benutzte Formeln:
B4: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;"Fehler"))
B5: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;"Fehler"))
B6: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;"Fehler"))
B7: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;"Fehler"))
C4: =GLÄTTEN(WECHSELN(A4;B4;""))
C5: =GLÄTTEN(WECHSELN(A5;B5;""))
C6: =GLÄTTEN(WECHSELN(A6;B6;""))
C7: =GLÄTTEN(WECHSELN(A7;B7;""))


Festgelegte Namen:
Drei: =LINKS(Tabelle1!A4;FINDEN(" ";Tabelle1!A4;FINDEN(" ";Tabelle1!A4)+1)-1) \*rel. Name, so gültig in B4
Leer: =LÄNGE(Tabelle1!A4)-LÄNGE(WECHSELN(Tabelle1!A4;" ";"")) \*rel. Name, so gültig in B4
Vier: =LINKS(Tabelle1!A4;FINDEN(" ";Tabelle1!A4;FINDEN(" ";Tabelle1!A4;FINDEN(" ";Tabelle1!A4)+1)+1)) \*rel. Name, so gültig in B4

A4:C7
haben das Zahlenformat: Standard

Tabellendarstellung erreicht mit dem Code in FAQ:2363

Gruß
Reinhard

Marylou · 3. September 2008 um 14:46

───────────────────────┴──────────────┘

Benutzte Formeln:
B4: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;„Fehler“))
B5: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;„Fehler“))
B6: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;„Fehler“))
B7: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;„Fehler“))
C4: =GLÄTTEN(WECHSELN(A4;B4;""))
C5: =GLÄTTEN(WECHSELN(A5;B5;""))
C6: =GLÄTTEN(WECHSELN(A6;B6;""))
C7: =GLÄTTEN(WECHSELN(A7;B7;""))

Festgelegte Namen:
Drei: =LINKS(Tabelle1!A4;FINDEN(" „;Tabelle1!A4;FINDEN(“
„;Tabelle1!A4)+1)-1) *rel. Name, so gültig in B4
Leer: =LÄNGE(Tabelle1!A4)-LÄNGE(WECHSELN(Tabelle1!A4;“ „;“"))
*rel. Name, so gültig in B4
Vier: =LINKS(Tabelle1!A4;FINDEN(" „;Tabelle1!A4;FINDEN(“
„;Tabelle1!A4;FINDEN(“ ";Tabelle1!A4)+1)+1)) *rel. Name, so
gültig in B4

A4:C7
haben das Zahlenformat: Standard

Tabellendarstellung erreicht mit dem Code in FAQ:2363

Gruß
Reinhard

So Reinhard,

auch das habe ich gleich ausprobiert, will es aber nicht hinbekommen, stell mich zu blöd an und komme auch nicht dahinter! Habe Deine erste Formel verwendet (um Straße und PLz von einander zu trennen) was ich mit den oben aufgeführten machen soll, weiß ich nicht, bin alle Variaten durch).

Ich will Dir danken für Deine Antworten und die damit verbundene Mühe!

Mit neidischen Grüßen (auf Dein kompetentes Wissen bzw. es auch umzusetzen ;O)

Liebe Grüße
Marie

Reinhard_fb8cb7 · 3. September 2008 um 15:40

Hi Marie,

deine Werte stehen in A4:A7, also sind die nachstehenden Formeln klar, daß du weißt wo du sie eingeben mußt:

B4: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;„Fehler“))
B5: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;„Fehler“))
B6: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;„Fehler“))
B7: =WENN(Leer=3;Drei;WENN(Leer=4;Vier;„Fehler“))
C4: =GLÄTTEN(WECHSELN(A4;B4;""))
C5: =GLÄTTEN(WECHSELN(A5;B5;""))
C6: =GLÄTTEN(WECHSELN(A6;B6;""))
C7: =GLÄTTEN(WECHSELN(A7;B7;""))

„*rel. Name, so gültig in B4“ bedeutet relativer Name, so gültig in B4 *ähem* *ups*.

Scheinbar kennst du dich mit Namen nicht so aus. Übersetzt heißt das, du mußt in Zelle B4 stehen, also sie muß markiert sein, dann kannst du über Einfügen–Namen die jeweiligen Namen für die jeweiligen Formeln vergeben.

Festgelegte Namen:
Drei: =LINKS(Tabelle1!A4;FINDEN(" „;Tabelle1!A4;FINDEN(“
„;Tabelle1!A4)+1)-1) *rel. Name, so gültig in B4
Leer: =LÄNGE(Tabelle1!A4)-LÄNGE(WECHSELN(Tabelle1!A4;“ „;“"))
*rel. Name, so gültig in B4
Vier: =LINKS(Tabelle1!A4;FINDEN(" „;Tabelle1!A4;FINDEN(“
„;Tabelle1!A4;FINDEN(“ ";Tabelle1!A4)+1)+1)) *rel. Name, so
gültig in B4

Auch wenn du jetzt anfänglich höchstwahrscheinlich durch „namen“ verwirrt bist, sie machen es letztlich viel übersichtlicher als lange Formelmonster

=WENN(Leer=3;Drei;WENN(Leer=4;Vier;„Fehler“))

ist, wenn man „Wenn“ verstanden hat rel. leicht zu "lesen, verglichen damit wenn da anstatt den Namen die jeweiligen Formeln auch noch drin stünden, dann wäre die Formel 200 bytes lang.

Gruß
Reinhard