Hallo Leute,
ich habe das Internet und diverse Foren schon ziemlich abgegrast und leider keine wirklich passende Lösung gefunden. Hier mal mein Problemchen. 
Ich habe eine Exceltabelle mit vielen verschiedenen Spalten und Tabellenblättern. Nur soviel, im Tabellenblatt A, in der Spalte K stehen die E-Mail-Adressen, an die ich eine Sammel-E-Mail mit einem Dateianhang (c:\xyz\4711.zip) schicken möchte.
Alle E-Mails sollen den gleichen Betreff und Inhaltstext und Anhang haben.
Wie bekomme ich das hin?
Ich habe schon ein Word-Dokument, mit dem ich eine Serien-E-Mail versende, leider kann ich an diese E-Mail kein Anhang dran tun,oder doch?
Wer kann mir da helfen?
Danke
Gruß
Ulf
Hi,
das kannst du mit VBA machen. Ein Muster findest du hier:
http://www.dicks-clicks.com/excel/olSending.htm
Das musst du jetzt so umbauen, dass in einer Schleife die email-Adressen in der entsprechenden Spalte gelesen werden und dann an diese (würde ich für jede einzeln machen) die Mail verschicken.
Ohne VBA wirst du da vermutlich nicht weiterkommen.
Hallo,
danke für Deine antwort, auch wenn sie für mich unbrauchbar ist.
Ich kann weder VBA noch Schleifen programmieren. Schleifen kann ich binden, nicht mehr und nicht weniger.
Kann mir sonst jemand helfen bzw. mir das VBA(Script?) schreiben?
Gruß
Ulf
Ich kann weder VBA noch Schleifen programmieren.
Hallo Ulf,
probieren wirs mal.
Mache Alt+F11, dann Einfügen—Modul, dortrein den nachstehenden Code kopieren.
Dann bei Extras–Verweise das Häkchen setzen bei „Microsoft Outlook X.0 Object Library“.
X ist deine Excelversion.
Dann stelle den Curser mitten in den Code und drücke F5.
Erscheint Outlook korrekt?
Sub SendWithAtt()
Dim olApp As Outlook.Application
Dim olMail As MailItem
Set olApp = New Outlook.Application
Set olMail = olApp.CreateItem(olMailItem)
With olMail
.To = "[email protected];[email protected];[email protected]"
.Subject = "Emailtest"
.Body = "Hallo," & Chr(13) & "anbei die Datei"
.Attachments.Add "c:\xyz\4711.zip"
.Display '.Send
End With
Set olMail = Nothing
Set olApp = Nothing
End Sub
Gruß
Reinhard
Hallo Reinhard,
Wahnsinn, es funktioniert. 
Nun sag mir bitte noch, wie ich nun die E-Mails aus dem Tabellenblatt „A“ und der Spalte „K“ auslese und dort eintrage/einfüge.
Ich Danke Dir jetzt schon tausend mal.
Gruß
Ulf
Hallo,
ich habe mal folgendes ausprobiert:
Sub SendWithAtt()
Dim olApp As Outlook.Application
Dim olMail As MailItem
For i = 2 To 160
Set olApp = New Outlook.Application
Set olMail = olApp.CreateItem(olMailItem)
With olMail
.To = „[email protected]“
.BCC = Cells(i, 11)
.Subject = „Newsletter“
.Body = „Hallo,“ & Chr(13) & Chr(13) & „Test Text“
.Attachments.Add „c:\xyz\0815.zip“
.Display '.Send
End With
Set olMail = Nothing
Set olApp = Nothing
Next i
End Sub
Soweit so gut, nun macht er daraus aber 159 E-Mails, anstatt nur einer.
Ich sagte doch, ich kann nur Schleifen binden, nicht sie programmieren.
Was muß ich da rein schreiben, das er 1 E-Mail mit bis zu 160 BCC Empfängern erstellt?
Gruß
Ulf
Nun sag mir bitte noch, wie ich nun die E-Mails aus dem
Tabellenblatt „A“ und der Spalte „K“ auslese und dort
eintrage/einfüge.
Hallo Ulf,
wenn alles klappen sollte kannst du das Hochkomma vor „.Send“ entfernen und die Zeile mit „.Display“ entfernen.
Option Explicit
Sub SendWithAtt()
Dim olApp As Outlook.Application, olMail As MailItem, Zei As Long
Dim An As String, wks As Worksheet
Set wks = Worksheets("A")
Set olApp = New Outlook.Application
Set olMail = olApp.CreateItem(olMailItem)
For Zei = 2 To wks.Cells(Rows.Count, 11).End(xlUp).Row
An = An & wks.Cells(Zei, 11) & ";"
Next Zei
An = Left(An, Len(An) - 1)
With olMail
.To = An
.Subject = "Emailtest"
.Body = "Hallo," & Chr(13) & "anbei die Datei"
.Attachments.Add "c:\xyz\4711.zip"
.Display
'.Send
End With
Set olMail = Nothing
Set olApp = Nothing
End Sub
'
Sub SendWithAtt2()
Dim olApp As Outlook.Application, olMail As MailItem, Zei As Long
Dim An As String, wks As Worksheet
Set wks = Worksheets("Tabelle1") '("A")
Set olApp = New Outlook.Application
Set olMail = olApp.CreateItem(olMailItem)
For Zei = 3 To wks.Cells(Rows.Count, 11).End(xlUp).Row
An = An & wks.Cells(Zei, 11) & ";"
Next Zei
An = Left(An, Len(An) - 1)
With olMail
.To = wks.Cells(2, 11)
.BCC = An
.Subject = "Emailtest"
.Body = "Hallo," & Chr(13) & "anbei die Datei"
.Attachments.Add "c:\xyz\4711.zip"
.Display
'.Send
End With
Set olMail = Nothing
Set olApp = Nothing
End Sub
Gruß
Reinhard
Hallo Reinhard,
Perfekt. Genau so soll es sein.
1 Trillion Mal Danke.
Gruß
Ulf