Dateien von mehreren Exceldaten kopieren

Computer: Software & Programmierung Office Software
1

Hallo,

ich bekomme mehrere Exceldateien ca. 100, die ich auswerten muss. Ziel dabei ist, das alle 100 Antworten, die in der Zelle B1 stehen in einer neuen Excelliste kopiert werden. Damit habe ich alle antworten zB. zur frage 1 in einer excelliste.

Die Exceldateien werden alle lokal in einem ordner abgespeichert. Hat jm eine Idee wie man sowas realisieren kann?

Danke im Voraus.

Mit freundlichen Grüßen

Wischnor

2

mehrere Exceldateien auslesen per Makro
Hi Wischnor,
ich bekomme mehrere Exceldateien ca. 100, die ich auswerten
muss. Ziel dabei ist, das alle 100 Antworten, die in der Zelle
B1 stehen in einer neuen Excelliste kopiert werden. Damit habe
ich alle antworten zB. zur frage 1 in einer excelliste.
Die Exceldateien werden alle lokal in einem ordner abgespeichert.
Neue Mappe, Alt+F11, Einfügen–Modul, Code reinkopieren, Editor schließen.
In Excel dann Alt+F8 um das Makro zu starten

Option Explicit
'
Sub DateienAuslesen()
Dim FSO As Object, oFolder As Object, oFiles As Object, oFile As Object
Dim strFolder As String, wkb As Workbook
Dim Zei
On Error GoTo Ende
Application.ScreenUpdating = False
strFolder = "h:\"
Set FSO = CreateObject("Scripting.FileSystemObject")
Set oFolder = FSO.getfolder(strFolder)
Set oFiles = oFolder.Files
With ThisWorkbook.Worksheets("Tabelle1")
 For Each oFile In oFiles
 If oFile.Name Like "\*.xls" Then
 Set wkb = Workbooks.Open(oFile)
 Zei = Zei + 1
 .Cells(Zei, 2) = wkb.Worksheets(1).Range("B1")
 wkb.Close False
 End If
 Next oFile
End With
Ende:
Application.ScreenUpdating = True
End Sub

Gruß
Reinhard

3

Hallo Reinhard,

Vielen Dank für deine Hilfe, es klappt. Super arbeit.

Viele Grüße aus Essen

Wischnor