Zum Inhalt springen
Frage 3. September 2007 · 48 Antworten

Einfach oder nicht ?

Nabend,

Ich habe auf einer Form 16 Punkte, die auf 2 reihen a 8 Punkte aufgeteilt sind. Nun würde ich gern einen Punkt aus der ersten reihe mit einem beliebigen aus reihe 2 verbinden. Zusätzlich würde ich gern in einer Liste den text bekommen:" Punkt 1 wurde mit Punkt 9 verbunden.
Die beiden Punkte sollten entweder mit der gleichen Farbe gekennzeichnet oder mit einer linie verbunden werden.

Wie gross wäre der Aufwand ?

besten Dank. mfg jonny

Diese Frage stammt aus dem Jahr 2007. Weißt du es heute besser?

Aktuelle Antwort ergänzen

48 Antworten

Hi Joe,

Wie gross wäre der Aufwand ?

zwei Zeilen. :smile: … und etwas drum herum.

Option Explicit

Dim Start As Integer

Private Sub Picture1\_Click(Index As Integer)
 Start = Index
End Sub

Private Sub Picture2\_Click(Index As Integer)
 Line (Picture1(Start).Left, Picture1(Start).Top)-(Picture2(Index).Left, Picture2(Index).Top)
End Sub

… läuft, getestet.

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, Wie gross wäre der Aufwand ? zwei Zeilen. :smile: … und etwas drum herum. Option Explicit Dim Start As Integer Private Sub Picture1\_Click(Index As Integer) Start = Index End Sub Private Sub Picture2\_Click(Index …

Im ersten Moment schien es überschaubar :stuck_out_tongue:
ich habe eine Form mit Picture1 & Picture2 + deinen Code.

Compile error:
Procedur declaration does not match description of event or procedure have the same name.

wir reden über vb6 (wie immer, oder)

Thx , joe

[Bei dieser Antwort wurde das Vollzitat nachträglich automatisiert entfernt]

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Im ersten Moment schien es überschaubar :stuck_out_tongue: ich habe eine Form mit Picture1 & Picture2 + deinen Code. Compile error: Procedur declaration does not match description of event or procedure have the same name …

Hi Joe,

Private Sub Picture1_Click(Index As Integer)

Die Eigenschaft ‚Index‘ haben nur Steuerelementefelder, die Pics zum anklicken in der einen Zeile heißen alle Picture1 und haben den Index von 0 bis 7, die anderen acht heißen Picture1 mit dem Index 0 bis 7.

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, Private Sub Picture1_Click(Index As Integer) Die Eigenschaft ‚Index‘ haben nur Steuerelementefelder, die Pics zum anklicken in der einen Zeile heißen alle Picture1 und haben den Index von 0 bis 7, die anderen ach …

WoW, nun bin ich schon beeindruckt!!
war wieder ein anfängerfehler von mir.

Nun habe ich das ganze bis Reihe 4 a 8 Pictures gebaut.
Wie kann ich sagen das von einem Punkt nur eine Linie weggehen darf. bzw wie könnte ich eine line wieder entfernen ?

Option Explicit

Dim Start As Integer

Private Sub Picture1\_Click(Index As Integer)
Start = Index
End Sub

Private Sub Picture2\_Click(Index As Integer)
Line (Picture1(Start).Left, Picture1(Start).Top)-(Picture2(Index).Left, Picture2(Index).Top)
End Sub

Private Sub Picture3\_Click(Index As Integer)
Line (Picture1(Start).Left, Picture1(Start).Top)-(Picture3(Index).Left, Picture3(Index).Top)
End Sub
0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

WoW, nun bin ich schon beeindruckt!! war wieder ein anfängerfehler von mir. Nun habe ich das ganze bis Reihe 4 a 8 Pictures gebaut. Wie kann ich sagen das von einem Punkt nur eine Linie weggehen darf. bzw wie könnte ich …

Hi Joe,

Nun habe ich das ganze bis Reihe 4 a 8 Pictures gebaut.

OK. Verschärfte Bedingungen. :smile:

Wie kann ich sagen das von einem Punkt nur eine Linie weggehen
darf.

Du kannst das Pic disablen. Beispiel:

Picture1(Index).enabled = False

Wenn die Linie vom picture1(Index) abgeht. In der Basisversion ist eine Reihe ja immer nur Start, die andere immer nur Ziel. Wenn das nicht so sein soll, wird der Code etwas komplizierter, aber nicht viel. Ursprünglich ging es ja um möglichst wenig Code. :smile:

bzw wie könnte ich eine line wieder entfernen ?

Indem Du für jedes Pic speicherst, daß eine Linie abgeht und wohin. Dazu nimmst Du am Besten zu jeder der Zeilen ein eigenes Array mit identischen Indizes und dimensioniert die als Objekt, dann hast Du alle Eigenschaften … Und schon sind wir mit dem einfachen Programm in der objektorientierten Programmierung angekommen. *fg* So schnell kann das gehen. Klar?

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, Nun habe ich das ganze bis Reihe 4 a 8 Pictures gebaut. OK. Verschärfte Bedingungen. :smile: Wie kann ich sagen das von einem Punkt nur eine Linie weggehen darf. Du kannst das Pic disablen. Beispiel: Picture1(Ind …

A hoi Rainer.
Array…Array …da war doch was.

  1. Wenn ich Picture1 index 0-15 brauche, also 16 Bilder pro reihe, muss ich auf Long umsteigen, oder?

  2. Picture1(Index).Enabled & Picture2(Index).Enabled = False
    Funktioniert bei Picture2 einbahnfrei. Aber bei Picture1 leider nicht sooo gut da beim disablen ja noch ein wert im index drinsteht. soll ich da einfach nach einem klick sagen index = „“ ?

  3. Wie war das mit einer Listbox die nach jedem klick sagt:
    Picture1 index1 wurde mit Picture2 index4 verbunden :confused:

danke mfg joe

[Bei dieser Antwort wurde das Vollzitat nachträglich automatisiert entfernt]

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

A hoi Rainer. Array…Array …da war doch was. Wenn ich Picture1 index 0-15 brauche, also 16 Bilder pro reihe, muss ich auf Long umsteigen, oder? Picture1(Index).Enabled & Picture2(Index).Enabled = False Funktioniert bei Pi …

Hi Joe,

Array…Array …da war doch was.

*gg*

  1. Wenn ich Picture1 index 0-15 brauche, also 16 Bilder pro
    reihe, muss ich auf Long umsteigen, oder?

Byte ist 1 Byte groß, ein Byte hat 8 Bit. 2^0 = 1 + 2^1 = 2 … + 2^7 = 128 … Summe 255. 1 Byte reicht also um bis 255 zu zählen. Integer ist 2 Byte groß, also 255 * 255 = 65025. Aber damit man negative Zahlen darstellen kann von -32512 bis +32512. Long hat 4 Byte, Double 8 Byte … ab hier darfst Du selbst rechnen.

  1. Picture1(Index).Enabled & Picture2(Index).Enabled = False
    Funktioniert bei Picture2 einbahnfrei. Aber bei Picture1
    leider nicht sooo gut da beim disablen ja noch ein wert im
    index drinsteht. soll ich da einfach nach einem klick sagen
    index = „“ ?

Index ist eine Variable, die Du vom System bekommst, das ist immer der Index des angeklickten Bildes. Wenn Du selbst Variablen setzen möchtest, verwende einen anderen Namen.

  1. Wie war das mit einer Listbox die nach jedem klick sagt:
    Picture1 index1 wurde mit Picture2 index4 verbunden :confused:

Aber nur für die Anzeige! Nicht, daß Du damit arbeiten willst, das wird extrem langsam, nicht zu gebrauchen.
Nimm eine Variable, ich würde die ‚Src‘ nennen. (Source) und deklariere sie als Integer. (Index ist ebenfalls Integer)
Wenn Du Deine Pics nun von 1 bis n numerierst (Null weg lassen, ein Array mit Pics reicht ja auch …) Dann kannst Du mit …

If Src = 0 Then
 Src = Index
Else
 Line (Pic(Src).Left, Pic(Src).Top) - (Pic(Index).Left, Pic(Index).Top), VbBlack
 List1.AddItem CStr(Src) & " - " & CStr(Index)
 Dest(Index) = Src
 Dest(src) = Index
End If

Sowohl die Linie ziehen als auch die Punkte in die Liste eintragen.
Für die Arbeit würde ich dann aber doch ein Array ‚Dest(Count)‘ anlegen und dort immer den Index des anderen Feldes eintragen, zu dem die Linie führt. (Oben schon mal eingebaut) Wenn Du ein Zeil eintragen willst und da steht schon eins, dann muss die Linie gelöscht werden. Das habe ich jetzt noch nicht eingebaut, versuch’s mal selbst.

Line (Pic(Dest(Index)).Left, Pic(Dest(Index)).Top) - (Pic(Index).Left, Pic(Index).Top), Me.BackColor

Gruß, Rainer

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

A hoi Rainer. Array…Array …da war doch was. Wenn ich Picture1 index 0-15 brauche, also 16 Bilder pro reihe, muss ich auf Long umsteigen, oder? Picture1(Index).Enabled & Picture2(Index).Enabled = False Funktioniert bei Pi …

Code …
Hi Joe,

erst lesen, wenn du nicht mehr weiter kommst:

Option Explicit

Dim Dest() As Integer
Dim Src As Integer

Private Sub Form\_Load()
 ReDim Dest(Pic.LBound To Pic.UBound)
End Sub

Private Sub Pic\_Click(Index As Integer)
 If Dest(Index) 0 Then
 Line (Pic(Index).Left, Pic(Index).Top)-(Pic(Dest(Index)).Left, Pic(Dest(Index)).Top), Me.BackColor
 Dest(Dest(Index)) = 0
 Dest(Index) = 0
 End If

 If Src = 0 Then
 Src = Index
 Pic(Index).BackColor = vbRed
 Else
 Line (Pic(Src).Left, Pic(Src).Top)-(Pic(Index).Left, Pic(Index).Top), vbBlack
 Pic(Src).BackColor = vbWhite
 Dest(Index) = Src
 Dest(Src) = Index
 Src = 0
 End If
End Sub

Es gibt nur ein Steuerelementefeld, die Pics heißen Pic(Index). Wo die liegen ist ja egal. Verwendest Du mehrere, wird nur der Code komplizierter, bringt aber keinen Nutzen.

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Code … Hi Joe, erst lesen, wenn du nicht mehr weiter kommst: Option Explicit Dim Dest() As Integer Dim Src As Integer Private Sub Form\_Load() ReDim Dest(Pic.LBound To Pic.UBound) End Sub Private Sub Pic\_Click(Index As …

Moin Rainer,
ich würde gern beide Bilder weiß einfärben nicht nur den startpunkt.
Es ist doch ein Array, also könnte ich mir zu jedem zeitpunkt alle verbindungen ausgeben lassen ? also Button press… 22->44, 2->10

? mfg jonny

[Bei dieser Antwort wurde das Vollzitat nachträglich automatisiert entfernt]

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Moin Rainer, ich würde gern beide Bilder weiß einfärben nicht nur den startpunkt. Es ist doch ein Array, also könnte ich mir zu jedem zeitpunkt alle verbindungen ausgeben lassen ? also Button press… 22->44, 2->10 ? mfg j …

Hi Joe,

ich würde gern beide Bilder weiß einfärben nicht nur den
startpunkt.

dann mach’s doch …

 Pic(Src).BackColor = vbWhite
 Pic(Index).BackColor = vbWhite

Es ist doch ein Array, also könnte ich mir zu jedem zeitpunkt
alle verbindungen ausgeben lassen ?

Ja, klar.

Private Sub Command1\_Click()  
 For i = LBound(Pic) To UBound(Pic)  
 List1.AddItem CStr(i) & " - " & CStr(Dest(i))  
 Next  
End Sub

aber wozu? Du siehst Die Linien doch.

Stopp! Das war falsch! Korrektur …

Private Sub Command1\_Click()
 Dim i As Integer
 List1.Clear
 For i = Pic.Lbound To Pic.Ubound
 List1.AddItem CStr(i) & " - " & CStr(Dest(i))
 Next
End Sub

So ist es besser.

Gruß, Rainer
PS. Schön, wenn man solche Fehler korrigieren kann. :smile:
Sollte mal Jemand so einen Wunsch haben, mach ich immer gern.

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, ich würde gern beide Bilder weiß einfärben nicht nur den startpunkt. dann mach’s doch … Pic(Src).BackColor = vbWhite Pic(Index).BackColor = vbWhite Es ist doch ein Array, also könnte ich mir zu jedem zeitpunkt al …

OT Nicht Lesenswert
Hallo Rainer,
Joe bleibt dir bis 2046 erhalten *sicherbin*
Aber dann steht sein/euer Programm
Lieben Gruß
Reinhard

0 Hilfreich
Antwort auf Reinhard_fb8cb7zum Beitrag ↑

OT Nicht Lesenswert Hallo Rainer, Joe bleibt dir bis 2046 erhalten *sicherbin* Aber dann steht sein/euer Programm Lieben Gruß Reinhard

Hallo reinhard,

Joe bleibt dir bis 2046 erhalten *sicherbin*

na hoffentlich! Das ist doch schön so. :smile:

Aber dann steht sein/euer Programm

Seine/unsere Programme. Das ist doch nicht nur eins. Dafür ist das Brett doch da.

Ich habe übrigens etwas neues, eine DLL um den in VB6/VBA fehlenden Befehl ‚Swap‘ zu realisieren, also den Inhalt von Variablen oder Bereichen in Arrays mit einem Befehl schnell auszutauschen.

Das hat mir/uns CMБ in Assembler (mit C++) geschrieben … wahnsinnig schnell!
http://www.winhome.de/ISwap.dll

Das musste ich einfach mal erzählen. :smile:

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hallo reinhard, Joe bleibt dir bis 2046 erhalten *sicherbin* na hoffentlich! Das ist doch schön so. :smile: Aber dann steht sein/euer Programm Seine/unsere Programme. Das ist doch nicht nur eins. Dafür ist das Brett doch …

Hallo Rainer,

Joe bleibt dir bis 2046 erhalten *sicherbin*

na hoffentlich! Das ist doch schön so. :smile:

Ja, einer muß ja das Licht ausmachen :smile:

Ich habe übrigens etwas neues, eine DLL um den in VB6/VBA
fehlenden Befehl ‚Swap‘ zu realisieren, also den Inhalt von
Variablen oder Bereichen in Arrays mit einem Befehl schnell
auszutauschen.

Das hat mir/uns CMБ in Assembler (mit C++) geschrieben
… wahnsinnig schnell!
http://www.winhome.de/ISwap.dll

Das musste ich einfach mal erzählen. :smile:

Okay, ich setze in Vba einen Verweis auf diese DLL, und dann?

Ich kenne swap nicht, mutmaße aber stark es läuft so

swap(x,y)

was dem entspricht

Merker=x
x=y
y=Merker

z.B. in Sortiercodes eingesetzt.

Jetzt weiß ich nicht wie das mit „Bereichen in Arrays“ gemeint ist.

swap(x(5),y(7)) macht mir irgendwie keinen Sinn

Also erzähle gerne weiter, ich lausche gerne *gg*

Gruß
Reinhard

0 Hilfreich
Antwort auf Reinhard_fb8cb7zum Beitrag ↑

Hallo Rainer, Joe bleibt dir bis 2046 erhalten *sicherbin* na hoffentlich! Das ist doch schön so. :smile: Ja, einer muß ja das Licht ausmachen :smile: Ich habe übrigens etwas neues, eine DLL um den in VB6/VBA fehlenden B …

Hallo Reinhard,

Okay, ich setze in Vba einen Verweis auf diese DLL, und dann?

Ich kenne swap nicht, mutmaße aber stark es läuft so

swap(x,y)

das kann noch mehr, nämlich mehrere Bytes in einem Schritt. Ich habe ein Demo dazu geschrieben und im Brett C++ gepostet …
http://www.wer-weiss-was.de/cgi-bin/forum/showarchiv…

swap(x(5),y(7)) macht mir irgendwie keinen Sinn

Swap (BitmapBytes(0),ByteArray(0),300000) kann aber Sinn machen. :smile:

Sieh Dir mal das Beispiel an …

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, ich würde gern beide Bilder weiß einfärben nicht nur den startpunkt. dann mach’s doch … Pic(Src).BackColor = vbWhite Pic(Index).BackColor = vbWhite Es ist doch ein Array, also könnte ich mir zu jedem zeitpunkt al …

Moin Rainer,
wochenende!! Habe zwar noch Rufbereitschaft aber wenn alles gut geht müsste ich paar stunden dem „Programmieren“ opfern können.
Wieso geht folgende zeile nicht ?
If Combovar = 1 And Combo1.ListIndex = 0 Then start = 5 and ende = 16

ich musste es in 2 zeilen aufteilen:

If Combovar = 1 And Combo1.ListIndex = 0 Then start = 5
If Combovar = 1 And Combo1.ListIndex = 0 Then ende = 16

und kannst du mir erklären was das CStr im folgenen Code für eine Funktion hat ? Ich bekomme die meldung expectet Array Lbound beim ausführen. Ich würde einfach gern einen Ist stand in text form haben wenn ich alle „ports“ verbunden habe.

besten Dank.
mfg joe

Private Sub Command1\_Click()
For i = LBound(Pic) To UBound(Pic)
List1.AddItem CStr(i) & " - " & CStr(Dest(i))
Next
End Sub
0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Moin Rainer, wochenende!! Habe zwar noch Rufbereitschaft aber wenn alles gut geht müsste ich paar stunden dem „Programmieren“ opfern können. Wieso geht folgende zeile nicht ? If Combovar = 1 And Combo1.ListIndex = 0 Then …

Hi Joe,

Wieso geht folgende zeile nicht ?
If Combovar = 1 And Combo1.ListIndex = 0 Then start = 5 and
ende = 16

das sind zwei Befehle und die kannst Du nicht durch And trennen, dafür ist der Doppelpunkt da.

ich musste es in 2 zeilen aufteilen:

If Combovar = 1 And Combo1.ListIndex = 0 Then start = 5
If Combovar = 1 And Combo1.ListIndex = 0 Then ende = 16

oder

If Combovar = 1 And Combo1.ListIndex = 0 Then start = 5: ende = 16

und kannst du mir erklären was das CStr im folgenen Code für
eine Funktion hat?

Cstr(i) wandelt die Zahl in der Variablen i in einen String um.
Mit Str$(i) bekommst Du für i=-1 ‚-1‘ zurück, für +1 ’ 1’
Private Sub Command1_Click()
For i = LBound(Pic) To UBound(Pic)
List1.AddItem CStr(i) & " - " & CStr(Dest(i))
Next
End Sub

Syntaxfehler.
Wenn Du wissen willst, welcher Index bei Dest() der Kleinste ist, schreibst Du LBound(Dest) .
Beim Steuerelement ist das aber eine Eigenschaft, dann sieht das so aus:

Pic.LBbound

Private Sub Command1\_Click()
 For i = Pic.LBound To Pic.UBound
 List1.AddItem CStr(i) & " - " & CStr(Dest(i))
 Next
End Sub

Sorry, da hatte ich Unfug geschrieben, wenn man nicht jede Zeile testet … :smile:

Gruß, Rainer

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Moin Rainer, wochenende!! Habe zwar noch Rufbereitschaft aber wenn alles gut geht müsste ich paar stunden dem „Programmieren“ opfern können. Wieso geht folgende zeile nicht ? If Combovar = 1 And Combo1.ListIndex = 0 Then …

Hi Joe,

Wieso geht folgende zeile nicht ?
If Combovar = 1 And Combo1.ListIndex = 0 Then start = 5 and
ende = 16
ich musste es in 2 zeilen aufteilen:
If Combovar = 1 And Combo1.ListIndex = 0 Then start = 5
If Combovar = 1 And Combo1.ListIndex = 0 Then ende = 16

Du hast „and“ mißverstanden. So geht das nicht. Nach Then folgt ein Befehl nicht zwei.

If Combovar = 1 And Combo1.ListIndex = 0 Then 
 start = 5 
 ende = 16
End If

Die restliche Kleinigkeit klärt Rainer *k.A. hab*

CStr wandelt einen beliebigen Wert in einen String um. Mit der Fehlermeldung kann ich nix anfangen, sorry :frowning:

Gruß
Reinhard

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Moin Rainer, wochenende!! Habe zwar noch Rufbereitschaft aber wenn alles gut geht müsste ich paar stunden dem „Programmieren“ opfern können. Wieso geht folgende zeile nicht ? If Combovar = 1 And Combo1.ListIndex = 0 Then …

Erstmal läuft alles. DANKE !!
ich melde mich wieder.

mfg Jonny.

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Code … Hi Joe, erst lesen, wenn du nicht mehr weiter kommst: Option Explicit Dim Dest() As Integer Dim Src As Integer Private Sub Form\_Load() ReDim Dest(Pic.LBound To Pic.UBound) End Sub Private Sub Pic\_Click(Index As …

Nabend Rainer,
ich würde gern zu jeder Linie die ich zwischen 2 Pics ziehe eine Input box bekommen wo ich zu der linie einen kurzen kommentar eintragen könnte. Wo setzte ich da an?

mfg jonny

Option Explicit

Dim Dest() As Integer
Dim Src As Integer

Private Sub Form_Load()
ReDim Dest(Pic.LBound To Pic.UBound)
End Sub

Private Sub Pic_Click(Index As Integer)
If Dest(Index) 0 Then
Line (Pic(Index).Left,
Pic(Index).Top)-(Pic(Dest(Index)).Left, Pic(Dest(Index)).Top),
Me.BackColor
Dest(Dest(Index)) = 0
Dest(Index) = 0
End If

If Src = 0 Then
Src = Index
Pic(Index).BackColor = vbRed
Else
Line (Pic(Src).Left, Pic(Src).Top)-(Pic(Index).Left,
Pic(Index).Top), vbBlack
Pic(Src).BackColor = vbWhite
Dest(Index) = Src
Dest(Src) = Index
Src = 0
End If
End Sub

Es gibt nur ein Steuerelementefeld, die Pics heißen
Pic(Index). Wo die liegen ist ja egal. Verwendest Du mehrere,
wird nur der Code komplizierter, bringt aber keinen Nutzen.

Gruß, Rainer

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Nabend Rainer, ich würde gern zu jeder Linie die ich zwischen 2 Pics ziehe eine Input box bekommen wo ich zu der linie einen kurzen kommentar eintragen könnte. Wo setzte ich da an? mfg jonny Option Explicit Dim Dest() As …

Hi Joe,

ich würde gern zu jeder Linie die ich zwischen 2 Pics ziehe
eine Input box bekommen wo ich zu der linie einen kurzen
kommentar eintragen könnte. Wo setzte ich da an?

am Besten genau da, wo die Linie gezogen wird, würde ich denken. Soll der Text angezeigt werden?

Option Explicit

Dim Dest() As Integer
Dim Kommentar() As String '<u>Kommentarfeld dimensionieren</u>
Dim Src As Integer

Private Sub Form\_Load()
 ReDim Dest(Pic.LBound To Pic.UBound)
 ReDim Kommentar(Pic.LBound To Pic.UBound)
End Sub

Private Sub Pic\_Click(Index As Integer)
 If Dest(Index) 0 Then
 Line (Pic(Index).Left, Pic(Index).Top)-(Pic(Dest(Index)).Left, Pic(Dest(Index)).Top), Me.BackColor
 Kommentar(Dest(Index)) = ""
 Kommentar(Index) = ""
 Dest(Dest(Index)) = 0
 Dest(Index) = 0
 End If

 If Src = 0 Then
 Src = Index
 Pic(Index).BackColor = vbRed
 Else

 Dest(Index) = Src
 Dest(Src) = Index
 Kommentar(Dest(Index)) = InputBox("Kommentar eingeben", "Kommentar")
 Kommentar(Index) = Kommentar(Dest(Index))
 Line (Pic(Src).Left, Pic(Src).Top)-(Pic(Index).Left, Pic(Index).Top), vbBlack
 Pic(Src).BackColor = vbWhite
 Src = 0
 End If
End Sub

Private Sub Command1\_Click()
 Dim i As Integer
 List1.Clear
 For i = Pic.LBound To Pic.UBound
 List1.AddItem CStr(i) & " - " & CStr(Dest(i))
 Next
End Sub

Im Array ‚Kommentar‘ steht der Text schon mal. Wie willst Du ihn anzeigen? Statt zu malen könnte man das ‚Line‘ Steuerelement nehmen und den Text in ‚ToolTipText‘ schreiben. Dann wird er angezeigt, wenn Du den Mauszeiger auf die Linie stellst … :smile:

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, ich würde gern zu jeder Linie die ich zwischen 2 Pics ziehe eine Input box bekommen wo ich zu der linie einen kurzen kommentar eintragen könnte. Wo setzte ich da an? am Besten genau da, wo die Linie gezogen wird, …

Moin Rainer,
ich habe den text nun auf die Pics gelegt
Pic(Src).ToolTipText = Kommentar(Dest(Index))
Pic(Index).ToolTipText = Kommentar(Index)
Es Funktioniert aber nicht immer. Also der text steht „drin“ aber der MousOver funktioniert leider nicht immer.
Wie könnte ich den Tooltip auch auf die Linie schreiben ? Line.tooltip gibt es doch nicht oder ?

Danke, mfg joe

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Moin Rainer, ich habe den text nun auf die Pics gelegt Pic(Src).ToolTipText = Kommentar(Dest(Index)) Pic(Index).ToolTipText = Kommentar(Index) Es Funktioniert aber nicht immer. Also der text steht „drin“ aber der MousOve …

Moin Joe,

ich habe den text nun auf die Pics gelegt
Pic(Src).ToolTipText = Kommentar(Dest(Index))
Pic(Index).ToolTipText = Kommentar(Index)
Es Funktioniert aber nicht immer. Also der text steht „drin“
aber der MousOver funktioniert leider nicht immer.

ToolTipText kommt mir auch manchmal ‚hakelig‘ vor.

Wie könnte ich den Tooltip auch auf die Linie schreiben ?
Line.tooltip gibt es doch nicht oder ?

Nein, ich habe gerade nachgesehen, auch das Line-Steuerelement hat keinen.

Was vermutlich gehen würde, wäre an die Linie ein ‚Etikett‘ zu hängen, entweder direkt auf die Form printen, ein Label … wenn es im Zweifelsfall lieber die Punkte verdecken soll als umgekehrt, werden es wohl Textfelder. Die kannst Du ja immer auf Text1(index).Visible = False stellen, wenn sie nicht angezeigt werden sollen …

Was auch noch geht, wäre den Text per API direkt in den Bildspeicher zu schreiben, Der verschwindet dann, sobald die Form bewegt wird, das ist aufwändig, wird viel Code, aber dann kannst Du den text sogar entlang der Linie legen und mußt kein waagrerechtes Fähnchen anhängen.

Gruß, Rainer
PS. Mal 'ne Fragge … darf man erfahren, was Du da baust? :smile:

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Moin Joe, ich habe den text nun auf die Pics gelegt Pic(Src).ToolTipText = Kommentar(Dest(Index)) Pic(Index).ToolTipText = Kommentar(Index) Es Funktioniert aber nicht immer. Also der text steht „drin“ aber der MousOver f …

Moin Rainer,
ich versuche ein Tool zu bauen welches mir auf der Arbeit 2-3 Zettel bzw. Zeit erspart.
Wir haben diverse Richtfunklinks. Jeder Standort hat mehrere RichtfunkModems die kreutz und quer mit 2Mbit Kabel verschaltet sind.
Leider stimmt der Ist zustand nur zu 70% mit dem Soll zustand überein.
deswegen habe ich mir nun dieses GRafische Tool gebastelt um die verkabelung schnellstmöglich mit dem Laptop aufzuzeichnen und im Büro abzugleichen. Die Beschriftung „Kommentar“ ist einfach wofür die verbindung gebraucht wird. Und ich bin bis jetzt über die funktion begeistert. mal schauen wie es sich in der Praxis macht.
Besten Dank!!

Eine frage wäre da aber noch:
Ich würde gern beim aufheben einer verbindung, das beide seiten wieder
Me.BackColor bekommen.
mfg jonny

Private Sub Pic\_Click(Index As Integer)
If Dest(Index) 0 Then
Line (Pic(Index).Left, Pic(Index).Top)-(Pic(Dest(Index)).Left, Pic(Dest(Index)).Top), Me.BackColor
Kommentar(Dest(Index)) = ""
Kommentar(Index) = ""
Dest(Dest(Index)) = 0
Dest(Index) = 0
End If
0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Moin Rainer, ich versuche ein Tool zu bauen welches mir auf der Arbeit 2-3 Zettel bzw. Zeit erspart. Wir haben diverse Richtfunklinks. Jeder Standort hat mehrere RichtfunkModems die kreutz und quer mit 2Mbit Kabel versch …

Hi Joe,

danke für die Erklärung. Das hilft beim Verständnis. Ich dache schon an ein Auswertungstool für die kommende Fussball-EM …

Eine frage wäre da aber noch:
Ich würde gern beim aufheben einer verbindung, das beide
seiten wieder

die füllst Du doch im Moment weiß…

 Pic(Src).BackColor = vbWhite
 Pic(Index).BackColor = vbWhite

… wenn die Linie gezogen wird. Wenn die Linie gelöscht wird kannst Du die ja wieder anders füllen …

 Pic(Src).BackColor = Me.BackColor
 Pic(Index).BackColor = Me.BackColor

… wenn Dir das besser gefällt.

Wie hast Du nun die Beschriftung vor? Ich bastel schon seit einiger Zeit daran herum, direkt die Linie zu beschriften, im selben Winkel, in dem die Linie verläuft … irgendwie ist heute nicht mein Tag, etwas mache ich falsch bei der Berechnung des Winkels. :smile: Danke für die Aufgabe, das ist ein nettes Rätsel, macht Spaß! *gg* Ich poste das Modul, wenn es fertig ist.

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, ich würde gern zu jeder Linie die ich zwischen 2 Pics ziehe eine Input box bekommen wo ich zu der linie einen kurzen kommentar eintragen könnte. Wo setzte ich da an? am Besten genau da, wo die Linie gezogen wird, …

OT Dim Dest() As Integer
Hallo Rainer,

vielleicht ist auch für mich heute nicht mein Verstehenstag :smile:
Dim Dest() As Integer
irritiert mich gewaltig, dummerweise habe ich hier grad kein Excel:frowning:

Aber ich bin aus dem Bauch heraus sicher, das würde in Excel Vba den Debugger anlocken.

Mag ja sein daß die einzelnen Items von Dest Integerwerte beinhalten, aber insgesamt ist Dest doch ein Array, eine Matrix o.ä.!?
Wie kann es da eine Integervariable sein?

Oder sehe ich da was falsch? *nichtunüblich*

Gruß
Reinhard

0 Hilfreich
Antwort auf Reinhard_fb8cb7zum Beitrag ↑

OT Dim Dest() As Integer Hallo Rainer, vielleicht ist auch für mich heute nicht mein Verstehenstag :smile: Dim Dest() As Integer irritiert mich gewaltig, dummerweise habe ich hier grad kein Excel:frowning: Aber ich bin a …

Hallo Reinhard,

vielleicht ist auch für mich heute nicht mein Verstehenstag

-)

Dim Dest() As Integer
irritiert mich gewaltig, dummerweise habe ich hier grad kein
Excel:frowning:

Aber ich bin aus dem Bauch heraus sicher, das würde in Excel
Vba den Debugger anlocken.

nein, damit hat VBA kein Problem.

Dim Dest() As Integer

deklariert ein Array aus Integer werten, nur ist noch nicht klar, wie groß das Array wird, das wird später mit

Redim Dest(Pic.Lbound to Pic.Ubound)

erst festgelegt. Das Array passt sich automatisch an die Anzahl der Pictures an. Wenn es z.B. vier Pictures gibt, wird das Array durch das Redim 8 Bytes groß.

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hallo Reinhard, vielleicht ist auch für mich heute nicht mein Verstehenstag -) Dim Dest() As Integer irritiert mich gewaltig, dummerweise habe ich hier grad kein Excel:frowning: Aber ich bin aus dem Bauch heraus sicher, …

Hallo Rainer,

nein, damit hat VBA kein Problem.

das habe ich dir sofort geglaubt, *schwör*

naja, weil ich so bin, natürlich erst nachdem ich

Sub tt()
Dim Dest() As Integer
ReDim Dest(1 To 5)
End Sub

getestet hatte :smile:)

Danke ^ Gruß
Reinhard

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, danke für die Erklärung. Das hilft beim Verständnis. Ich dache schon an ein Auswertungstool für die kommende Fussball-EM … Eine frage wäre da aber noch: Ich würde gern beim aufheben einer verbindung, das beide se …

Moin Rainer,

Ich sage nicht nein zum Modul, aber macht es bei mir nur sinn wenn es eine Option gibt die linie nicht durch andere Pics laufen zu lassen.
ich habe nun schon 6 zeilen mit 16 Pics. und es lässt sich nicht vermeiden das wenn ich zeile 1 mit zeile 6 verbinde die Linie durch andere Pics läuft. ist nicht weiter wild das ich mir das ganze ja nach dem eintragen als Text ausgeben lasse.

Was ich noch klären muss wäre speichern und laden … dazu aber später, wenn ich von der arbeit komme …

besten dank !!! mfg joe

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Moin Rainer, ich versuche ein Tool zu bauen welches mir auf der Arbeit 2-3 Zettel bzw. Zeit erspart. Wir haben diverse Richtfunklinks. Jeder Standort hat mehrere RichtfunkModems die kreutz und quer mit 2Mbit Kabel versch …

Hi Joe,

Zwischenergebnis, sieh mal. ob Du etwas davon gebrauchen kannst.

In der Form:

Option Explicit

Private Declare Function CreateFont Lib "gdi32" Alias \_
 "CreateFontA" (ByVal H As Long, ByVal w As Long, \_
 ByVal E As Long, ByVal O As Long, ByVal w As \_
 Long, ByVal i As Long, ByVal u As Long, ByVal S \_
 As Long, ByVal C As Long, ByVal OP As Long, ByVal \_
 CP As Long, ByVal Q As Long, ByVal PAF As Long, \_
 ByVal F As String) As Long
 
Private Declare Function SelectObject Lib "gdi32" (ByVal \_
 hdc As Long, ByVal hObject As Long) As Long
 
Private Declare Function DeleteObject Lib "gdi32" (ByVal \_
 hObject As Long) As Long
 
Private Declare Function TextOut Lib "gdi32" Alias "TextOutA" \_
 (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, \_
 ByVal lpString As String, ByVal nCount As Long) As Long
 
Dim x&, y&

Dim Dest() As Integer
Dim Kommentar() As String
Dim Src As Integer

Private Sub Form\_Load()
 ReDim Dest(Pic.LBound To Pic.UBound)
 ReDim Kommentar(Pic.LBound To Pic.UBound)
End Sub

Private Sub anzeigen()
 Dim w As Long
 Dim i As Integer
 Me.Cls
 For i = Pic.LBound To Pic.UBound
 If Dest(i) 0 Then
 w = -Winkel(Pic(i).Left, Pic(i).Top, Pic(Dest(i)).Left, Pic(Dest(i)).Top)
 TOut Pic(i).Left, Pic(i).Top, w, 12, " " + Kommentar(i)
 Line (Pic(Dest(i)).Left, Pic(Dest(i)).Top)-(Pic(i).Left, Pic(i).Top), vbBlack
 End If
 Next
End Sub

Private Sub Pic\_Click(Index As Integer)
 Dim w As Long
 If Dest(Index) 0 Then
 Kommentar(Dest(Index)) = ""
 Kommentar(Index) = ""
 Pic(Index).BackColor = Me.BackColor
 Pic(Dest(Index)).BackColor = Me.BackColor
 Dest(Dest(Index)) = 0
 Dest(Index) = 0
 End If

 If Src = 0 Then
 Src = Index
 Pic(Index).BackColor = vbRed
 Else

 Dest(Index) = Src
 Dest(Src) = Index
 Kommentar(Dest(Index)) = InputBox("Kommentar eingeben", "Kommentar")
 Kommentar(Index) = Kommentar(Dest(Index))
 anzeigen
 Pic(Src).BackColor = vbWhite
 Pic(Dest(Src)).BackColor = vbWhite
 Src = 0
 End If
End Sub

Private Sub Command1\_Click()
 Dim i As Integer
 List1.Clear
 For i = Pic.LBound To Pic.UBound
 List1.AddItem CStr(i) & " - " & CStr(Dest(i)) + " - " + Kommentar(i)
 Next
End Sub

Private Sub TOut(x&, y&, Winkel&, Size%, Text$)
 Dim hFont&, FontMem&, Bold&, Result&
 
 If Me.FontBold Then
 Bold = 700
 Else
 Bold = 400
 End If
 
 hFont = CreateFont(-Size, 0, Winkel \* 10, 0, Bold, \_
 Me.FontItalic, Me.FontUnderline, 0, 1, 4, &H10, \_
 2, 4, "Arial")
 
 FontMem = SelectObject(Me.hdc, hFont)
 Result = TextOut(Me.hdc, x, y, Text, Len(Text))
 Result = SelectObject(Me.hdc, FontMem)
 Result = DeleteObject(hFont)
End Sub

Dann musst Du noch ein Modul hinzufügen, die Winkelberechnung wollte ich nicht auch noch in der Form haben.

Im Modul:

Option Explicit

Public Const Pi = 3.14159265358979

Public Function Winkel(ByVal xt As Integer, ByVal yt As Integer, \_
 ByVal xb As Integer, ByVal yb As Integer) As Long

 Dim alpha As Double
 Dim atan As Double
 Dim dx As Integer
 Dim dy As Integer
 Dim hyp As Integer
 Dim SinAlpha As Single
 Dim CosAlpha As Single
 Dim w As Single
 Dim sel As Integer

 dx = xb - xt
 dy = yb - yt
 hyp = Sqr(dx ^ 2 + dy ^ 2)
 SinAlpha = dy / hyp
 CosAlpha = dx / hyp

 If Sqr(-SinAlpha \* SinAlpha + 1) \> 0 Then
 Winkel = Atn(SinAlpha / Sqr(-SinAlpha \* SinAlpha + 1)) / Pi \* 180
 Else
 Winkel = 90
 End If

 sel = Sgn(SinAlpha) + (2 \* Sgn(CosAlpha))

 Select Case sel
 Case -3
 Winkel = 180 + Abs(Winkel)
 Case -1
 Winkel = 180 - Winkel
 Case 1
 Winkel = 360 - Abs(Winkel)
 Case Else

 End Select
 If Winkel = 90 Or Winkel = 270 Then
 Winkel = Winkel + 180
 End If
 If Winkel = 0 And xt \> xb Then
 Winkel = 180
 End If

End Function

Inzwischen ist der Code doch etwas umfangreicher. Verstehst Du noch alles?

Gruß, Rainer

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Moin Rainer, Ich sage nicht nein zum Modul, aber macht es bei mir nur sinn wenn es eine Option gibt die linie nicht durch andere Pics laufen zu lassen. ich habe nun schon 6 zeilen mit 16 Pics. und es lässt sich nicht ver …

Hi Joe,

*gg* Zeitgleich … Sieh Dir mal den neuen Code an. :smile:

Speichern und laden wird leicht.

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, *gg* Zeitgleich … Sieh Dir mal den neuen Code an. :smile: Speichern und laden wird leicht. Gruß, Rainer

Moin Rainer,

Ich habe ein Frame hinter eine Pic reihe gelegt und in den Hintergrund gedrückt. Die Pics sind nun auf dem Frame so wie ich es wollte, nur die Linie zwischen den Pics wird leider von dem Frame verdeckt. Warum ?

In eine Datei schreiben sollte so klappen oder ?
Aber wie schreibe ich die Kommentare vom tooltip mit dazu `?

ff = FreeFile
 Open "line.cfg" For Output As #ff
 For i = Pic.LBound To Pic.UBound
 Print #ff, CStr(i) & "---" & Cstr(Dest(i)) 
 Next
Close #ff

mfg jonny

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Moin Rainer, Ich habe ein Frame hinter eine Pic reihe gelegt und in den Hintergrund gedrückt. Die Pics sind nun auf dem Frame so wie ich es wollte, nur die Linie zwischen den Pics wird leider von dem Frame verdeckt. Waru …

Moin Joe,

Ich habe ein Frame hinter eine Pic reihe gelegt und in den
Hintergrund gedrückt. Die Pics sind nun auf dem Frame so wie
ich es wollte,

so weit schön.

nur die Linie zwischen den Pics wird leider von
dem Frame verdeckt. Warum ?

Weil Du nach wie vor mit Me.Line()-() die Linien auf die Form malst und die vom Frame verdeckt werden. Der Line-Befehl ist jetzt mit dem Frame nicht mehr zu gebrauchen, denn auf den Frame kannst Du nicht malen.

da ist umbau angesagt, Du brauchst ein Array mit Line-Steuerelementen.
Wo die hin sollen berechnest Du ja schon, Du musst nur die vier Werte aus dem Line-Befehl in die Eigenschften x1,x1,x2,y2 des Line Steuerelements schreiben. Statt der Farben schreibst Du noch .Visible = True oder False und es geht wieder.

In eine Datei schreiben sollte so klappen oder ?
Aber wie schreibe ich die Kommentare vom tooltip mit dazu
`?

ff = FreeFile
 Open "line.cfg" For Output As #ff
 For i = Pic.LBound To Pic.UBound
 Print #ff ,Dest(i)
 Print #ff ,Kommentar(i)
 Next
 Close #ff

Wozu die Umwandlung in einen String? Der Counter ist überflüssig.

Du darfst ruhig mehrere verschiedene Werte schreiben, Du musst nur genau so lesen.

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Moin Joe, Ich habe ein Frame hinter eine Pic reihe gelegt und in den Hintergrund gedrückt. Die Pics sind nun auf dem Frame so wie ich es wollte, so weit schön. nur die Linie zwischen den Pics wird leider von dem Frame ve …

Moin,
Argh, ich verwende erstmal ein Shape für den Rahmen. :confused:
Und bau die speicherfunkton ein.

Melde mich später, Thx mfg joe

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Moin, Argh, ich verwende erstmal ein Shape für den Rahmen. :confused: Und bau die speicherfunkton ein. Melde mich später, Thx mfg joe

Abend Schoin,
Ich möchte nun noch ein textfeld der Linie und dem Kommentar anfügen.
Warum ist hier Script out of Range ?
Für micht steht da: Textfeld(1) = Link1(1).text

Private Sub Link1\_Change(Index As Integer)
Dim Textfeld() As String
Textfeld(Index) = Link1(Index).Text
End Sub

mfg joe

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Abend Schoin, Ich möchte nun noch ein textfeld der Linie und dem Kommentar anfügen. Warum ist hier Script out of Range ? Für micht steht da: Textfeld(1) = Link1(1).text Private Sub Link1\_Change(Index As Integer) Dim Tex …

Es fehlt das: For i = textfeld.LBound To textfeld.UBound oder ?

[Bei dieser Antwort wurde das Vollzitat nachträglich automatisiert entfernt]

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Es fehlt das: For i = textfeld.LBound To textfeld.UBound oder ? [Bei dieser Antwort wurde das Vollzitat nachträglich automatisiert entfernt]

Es wird Zeit das ich mir nochmal die BAsics reinpfeife.

Private Sub Form\_Load()
ReDim Dest(Pic.LBound To Pic.UBound)
ReDim Kommentar(Pic.LBound To Pic.UBound)
ReDim Textfeld(Pic.LBound To Pic.UBound)
End Sub

Private Sub Link1\_Change(Index As Integer)
Textfeld(Pic(Index)) = Link1(Index).Text
End Sub


'Laden
Open Ppfad For Input As #ff
 For i = Pic.LBound To Pic.UBound
 Input #ff, Dest(i)
 Input #ff, Kommentar(i)
 Input #ff, Textfeld(i)
 Link1(Pic(i)).Text = Textfeld(i) 
 Next
Close #ff

'Speichern
Private Sub Speichern\_Click()
ff = FreeFile
 pfd = App.Path
 If Right(pfd, 1) "\" Then pfd = pfd & "\"
 Ppfad = pfd & "Link.cfg"

Open Ppfad For Output As #ff
 For i = Pic.LBound To Pic.UBound
 Print #ff, Dest(i)
 Print #ff, Kommentar(i)
 Print #ff, Textfeld(i)
 Next
Close #ff
End Sub
0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Abend Schoin, Ich möchte nun noch ein textfeld der Linie und dem Kommentar anfügen. Warum ist hier Script out of Range ? Für micht steht da: Textfeld(1) = Link1(1).text Private Sub Link1\_Change(Index As Integer) Dim Tex …

Hi Joe,

*gg* da hebe ich doch gerade falsch gelesen, noch einmal … :smile:

Ich möchte nun noch ein textfeld der Linie und dem Kommentar
anfügen.
Warum ist hier Script out of Range ?

Es ist nicht dimensioniert.

Für micht steht da: Textfeld(1) = Link1(1).text

Private Sub Link1\_Change(Index As Integer)
 Dim Textfeld() As String
 Textfeld(Index) = Link1(Index).Text
End Sub

Dim textfeld() As String ist der erste Schritt, da fehlt noch ein ReDim Textfeld(von to bis)

Gruß, Rainer

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Es wird Zeit das ich mir nochmal die BAsics reinpfeife. Private Sub Form\_Load() ReDim Dest(Pic.LBound To Pic.UBound) ReDim Kommentar(Pic.LBound To Pic.UBound) ReDim Textfeld(Pic.LBound To Pic.UBound) End Sub Private Sub …

Beim Laden bekomme ich den fehler:
Control Array 16 doesnt exist. hmpf
Link1(i).Text = Textvomtextfeld(i)

Private Sub Form\_Load()
ReDim Dest(Pic.LBound To Pic.UBound)
ReDim Kommentar(Pic.LBound To Pic.UBound)
ReDim Textvomtextfeld(Pic.LBound To Pic.UBound)
End Sub

Private Sub Laden\_Click()
ff = FreeFile
pfd = App.Path
If Right(pfd, 1) "\" Then pfd = pfd & "\"
 Ppfad = pfd & "Link.cfg"
 Picopen = pfd & "open.bmp"
 Picclose = pfd & "close.bmp"

Open Ppfad For Input As #ff
 For i = Pic.LBound To Pic.UBound
 Input #ff, Dest(i)
 Input #ff, Kommentar(i)
 Input #ff, Textvomtextfeld(i)
 Link1(i).Text = Textvomtextfeld(i)
 Next
Close #ff

End Sub
0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Es wird Zeit das ich mir nochmal die BAsics reinpfeife. Private Sub Form\_Load() ReDim Dest(Pic.LBound To Pic.UBound) ReDim Kommentar(Pic.LBound To Pic.UBound) ReDim Textfeld(Pic.LBound To Pic.UBound) End Sub Private Sub …

Hi Joe,

Was ist ‚Link1(Index).Text‘?

Hmmm, kommentier mal die Laderoutine aus und sorge so dafür, daß erst mal etwas gesichert wird. Sonst fällt mir an dem Code im Moment nichts auf. Was geht nicht?

Gruß, Rainer

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Beim Laden bekomme ich den fehler: Control Array 16 doesnt exist. hmpf Link1(i).Text = Textvomtextfeld(i) Private Sub Form\_Load() ReDim Dest(Pic.LBound To Pic.UBound) ReDim Kommentar(Pic.LBound To Pic.UBound) ReDim Text …

Hi Joe,

Beim Laden bekomme ich den fehler:
Control Array 16 doesnt exist. hmpf
Link1(i).Text = Textvomtextfeld(i)

und, existiert es? Was ist Link1()?

Private Sub Form\_Load()
ReDim Dest(Pic.LBound To Pic.UBound)
ReDim Kommentar(Pic.LBound To Pic.UBound)
ReDim Textvomtextfeld(Pic.LBound To Pic.UBound)
End Sub

Private Sub Laden\_Click()
ff = FreeFile
pfd = App.Path
If Right(pfd, 1) "\" Then pfd = pfd & "\"
 Ppfad = pfd & "Link.cfg"
 Picopen = pfd & "open.bmp"
 Picclose = pfd & "close.bmp"

Open Ppfad For Input As #ff
 For i = Pic.LBound To Pic.UBound
 Input #ff, Dest(i)
 Input #ff, Kommentar(i)
 Input #ff, Textvomtextfeld(i)
 Link1(i).Text = Textvomtextfeld(i)
 Next
Close #ff

End Sub

ähhmmmm, gibt das nicht immer Probleme, direkt in ein Array zu laden?

Open Ppfad For Input As #ff
 For i = Pic.LBound To Pic.UBound
 input #ff, Wert
 Dest(i)= Wert
 Input #ff, Wert
 Kommentar(i)= Wert
 Input #ff, Wert
 Textvomtextfeld(i) = Wert
 Link1(i).Text = Textvomtextfeld(i)
 Next
Close #ff

Ich glaube, so würde da bei mir aussehen.

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, Beim Laden bekomme ich den fehler: Control Array 16 doesnt exist. hmpf Link1(i).Text = Textvomtextfeld(i) und, existiert es? Was ist Link1()? Private Sub Form\_Load() ReDim Dest(Pic.LBound To Pic.UBound) ReDim Ko …

Hi Rainer,
Ich konnte alle Probleme lösen …Es bedarf nur an etwas mehr Zeit :stuck_out_tongue:

Naja eine Frage hätte ich da noch.
wenn ich nun verschiedene Files/configurationen lade bleiben die Linien aus der davor geladenen Konfiguration auf dem Form.
ein Form1.Refresh löscht leider auch die aktuellen.
Kann ich die Linien vor dem laden irgendwie enfernen ?

mfg jonny

(Ps. habe leider keine Ahnung vom Excel / nicht viel zeit :///

mfg jonny

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Hi Rainer, Ich konnte alle Probleme lösen …Es bedarf nur an etwas mehr Zeit :stuck_out_tongue: Naja eine Frage hätte ich da noch. wenn ich nun verschiedene Files/configurationen lade bleiben die Linien aus der davor gela …

Hi Joe,

Ich konnte alle Probleme lösen …Es bedarf nur an etwas mehr
Zeit :stuck_out_tongue:

na also, geht doch … :smile:

Naja eine Frage hätte ich da noch.
wenn ich nun verschiedene Files/configurationen lade bleiben
die Linien aus der davor geladenen Konfiguration auf dem Form.

Ja, die sind ja Bestandteil des Bildes (Image).

ein Form1.Refresh löscht leider auch die aktuellen.

Nur wenn Du die erst malst und dann die Form löschst. Aber warum solltest Du das tun? Übrigens … hast Du die Form auf Autoredraw = True? Falls nein, minimiere mal die Form und mach sie wieder auf, dann sind alle Linien weg. Mit Me.Autoredraw = True nicht.

Kann ich die Linien vor dem laden irgendwie enfernen ?

Ja, mit der Hintergrundfarbe ‚übermalen‘. Das hat den selben Effekt, wie Me.CLS.

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, Ich konnte alle Probleme lösen …Es bedarf nur an etwas mehr Zeit :stuck_out_tongue: na also, geht doch … :smile: Naja eine Frage hätte ich da noch. wenn ich nun verschiedene Files/configurationen lade bleiben die …

Hi Rainer,
das ist meine Letzte frage zu diesem Thema!! :stuck_out_tongue:

Ich möchte kommentar(i) ausgeben lassen.
Nur habe ich das Problem das Jeder Inhalt 2x auftaucht.
Also zb in Kommentar(10) und Kommentar(20) steht das gleiche. Ich möchte aber nur eines von dem beiden in der Liste angezeigt bekommen.
wie löse ich das ?
mfg joe

Private Sub Command1\_Click()
Dim I As Integer
For I = Pic.LBound To Pic.UBound
 If Kommentar(I) = "" Or Kommentar(I) = " " Then
 Else
 List2.AddItem Kommentar(I)
 End If
Next
End Sub
0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Hi Rainer, das ist meine Letzte frage zu diesem Thema!! :stuck_out_tongue: Ich möchte kommentar(i) ausgeben lassen. Nur habe ich das Problem das Jeder Inhalt 2x auftaucht. Also zb in Kommentar(10) und Kommentar(20) steht …

das ist meine Letzte frage zu diesem Thema!! :stuck_out_tongue:

Hallo Rainer,
ich erhöhe auf 2 3 46 :smile:)
Lieben Gruß
Reinhard

0 Hilfreich
Antwort auf Reinhard_fb8cb7zum Beitrag ↑

das ist meine Letzte frage zu diesem Thema!! :stuck_out_tongue: Hallo Rainer, ich erhöhe auf 2 3 46 :smile:) Lieben Gruß Reinhard

MOrgen Schoin,
das richt nach einem Insider … ? egal ich biete 3058. was auch immer das heissen mag :stuck_out_tongue:

erfolgreichen arbeitstag … mfg Joe

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

Hi Rainer, das ist meine Letzte frage zu diesem Thema!! :stuck_out_tongue: Ich möchte kommentar(i) ausgeben lassen. Nur habe ich das Problem das Jeder Inhalt 2x auftaucht. Also zb in Kommentar(10) und Kommentar(20) steht …

Hi Joe,

das ist meine Letzte frage zu diesem Thema!! :stuck_out_tongue:

Ich möchte kommentar(i) ausgeben lassen.
Nur habe ich das Problem das Jeder Inhalt 2x auftaucht.
Also zb in Kommentar(10) und Kommentar(20) steht das gleiche.
Ich möchte aber nur eines von dem beiden in der Liste
angezeigt bekommen.
wie löse ich das ?

hmmm, dann steht der Kommentar aber auch für künftige Ausgaben nur ein mal zur Verfügung. Je nachdem, wie Du den Text ausgibst, kann es dann passieren, daß er Kopf steht.

Wenn Du das so möchtest, dann trage den Text doch gleich nur ein mal ein. Du siehst die Stelle im Code?

Private Sub Pic\_Click(Index As Integer)
 Dim w As Long
 If Dest(Index) 0 Then
 Kommentar(Dest(Index)) = ""
 Kommentar(Index) = ""
 Pic(Index).BackColor = Me.BackColor
 Pic(Dest(Index)).BackColor = Me.BackColor
 Dest(Dest(Index)) = 0
 Dest(Index) = 0
 End If

 If Src = 0 Then
 Src = Index
 Pic(Index).BackColor = vbRed
 Else

 Dest(Index) = Src
 Dest(Src) = Index
 Kommentar(Dest(Index)) = InputBox("Kommentar eingeben", "Kommentar")
**Kommentar(Index) = Kommentar(Dest(Index))**
 anzeigen
 Pic(Src).BackColor = vbWhite
 Pic(Dest(Src)).BackColor = vbWhite
 Src = 0
 End If
End Sub

Lass einfach die fett markierte Zeile weg, das ist der Eintrag, den Du mit Deinem Code löschen willst.

Gruß, Rainer

0 Hilfreich
Antwort auf Joe_515c88zum Beitrag ↑

MOrgen Schoin, das richt nach einem Insider … ? egal ich biete 3058. was auch immer das heissen mag :stuck_out_tongue: erfolgreichen arbeitstag … mfg Joe

Hi Joe,

das richt nach einem Insider … ?

Ja, und Du hast einen Teil davon gelesen. :smile:
Reinhard hatte die Prognose aufgestellt, daß Du uns hier bis 2043 erhalten bleibst. Das ging auf meine Ankündigung zurück, daß meine Vorfahren alle etwa 75 geworden sind, ich das Brett also 2030 wohl nicht mehr moderiere, weil ich so alt nicht werde. :smile:

Gruß, Rainer

0 Hilfreich
Antwort auf Chewpapa_22ca98zum Beitrag ↑

Hi Joe, das richt nach einem Insider … ? Ja, und Du hast einen Teil davon gelesen. :smile: Reinhard hatte die Prognose aufgestellt, daß Du uns hier bis 2043 erhalten bleibst. Das ging auf meine Ankündigung zurück, daß me …

Nabend Ihr 2 :stuck_out_tongue:

Rechne rechne. 2043.
Da bin ich so ca.60 = Hardcoregamer im Altersheim. Licht aus und zoggn bis der notarzt kommt. Aber bis dahin werde ich meine Zeit noch „sinnvoll“ gestalten. Zbsp. In diesem TOP Forum. Achtung kurze schleimatacke. Ich bin vor ca einem JAhr auf dieses Forum aufmerksam geworden und seitdem „süchtig“ TOp Leute mit einem TOP skill. und ich hoffe das ich ab 2008, sogut in VB bin um hier auch etwas von dem erlesenen wissen zurückgeben zu dürfen.
Ich werde meinen sohn (1,5 Jahre) in dieses Forum einarbeiten sodas ich nun eine 2080 bieten kann :stuck_out_tongue:

macht so weiter mfg jonny

0 Hilfreich

Deine Antwort

Zum Antworten bitte anmelden oder kostenlos registrieren.