Guten Tag
In der Optik ist es uraltes Wissen - Blau-auf-Schwarz sieht „man“ nicht wirklich…
Der Indikator, dass ein Filter gesetzt ist, wird aber genau Blau angezeigt. Eine Tabelle nach gesetzten Filternspalten zu durchsuchen bei mehr als 10 Spalten wird nahezu unmöglich.
Wer weiss, ob und wie statt Blau auf zB Weiss oder eine andere Farbe gewechselt werden kann…?
Vielen Dank - Gruss, Pete
Hallo Pete,
Wer weiss, ob und wie statt Blau auf zB Weiss oder eine andere
Farbe gewechselt werden kann…?
Das ist meines Wissens Excel-Intern nicht möglich.
Ich habe aber noch folgenden Workaround von Thomas Ramel gefunden,
der die entsprechende Zelle der gefilterten Spalte einfärbt (danke Thomas). Vielleicht hilft Dir das weiter. (Hoffe, ich verstoße damit nicht gegen die WWW-Etikette.)
Gruß
Rolf
Zitat:
Verwende in einer Zeile oberhalb der Überschriften die folgende Funktion (in einem Standardmodul) mit jeweils einem Bezug zur ersten Zeile unterhalb der Überschriften - es wird dann in den gefilterten Spalten jeweils das Filterkirterium dargestellt - bei Bedarf kannst Du diese Zellen dann über die Bedingte Formatierung einfärben, damit sogleich ins Auge springt, nach welchen Spalten gefiltert wurde.
Public Function AF\_KRIT(Bereich As Range) As String
'Quelle: Thomas Ramel
'Liest die Kriterien des Autofilters aus und listet diese in einer Zelle
'Als Bezug wird die erste Zelle nach dem Spaltentitel angegeben:
'AF\_KRIT(A2)
Dim s\_Filter As String
s\_Filter = ""
On Error GoTo Ende
With Bereich.Parent.AutoFilter
With .Filters(Bereich.Column - .Range.Column + 1)
s\_Filter = .Criteria1
Select Case .Operator
Case xlAnd
s\_Filter = s\_Filter & " UND " & .Criteria2
Case xlOr
s\_Filter = s\_Filter & " ODER " & .Criteria2
End Select
End With
End With
Ende:
AF\_KRIT = s\_Filter
End Function
Wenn Du die genannte Funktion direkt in einem allgemeinen Modul deiner Mappe speicherst, dann kannst Du auch ohne Hilfszellen direkt in der
Bedingten Formatierung der Spaltenüberschriftszellen darauf zugreifen:
Bedingte Formatierung - ‚Formel ist:‘
=AF_KRIT(A$2)""
- gewünschtes Zellenformat einstellen
Nach jedem Wechsel der Filter-Kriterien werden die Spaltenüberschriften nun entsprechend dargestellt.
Ein weitere Möglichkeit: Schreibe für dein Tabellenblatt ein Makro Selction Change.
Sobald nach dem Filtern in eine andere Zelle geklickt wird, wird die Zelle mit dem aktiven Filter farbig hinterlegt.
Private Sub Worksheet\_SelectionChange(ByVal Target As Range)
'Quelle: Peter H. Erdmann
Dim i As Integer
Dim b As Boolean
For i = 1 To ActiveSheet.Columns.Count
On Error GoTo ende
If ActiveSheet.AutoFilterMode Then
b = ActiveSheet.AutoFilter.Filters(i).On
If b = True Then
Cells(1, i).Interior.ColorIndex = 3
Else
Cells(1, i).Interior.ColorIndex = xlColorIndexNone
End If
End If
Next i
Exit Sub
ende:
End Sub
Zitat Ende
Herzlichen Dank an Rolf - es klappt und funktioniert genügend gut.
Bester Gruss, Pete