Mehr als sieben Verschachtelung bei Wennfunktion?

Sabrina_Weber · 12. November 2019 um 13:36

Hallo,

ich benutze Excell 2010 aber meine Funktionen sollten auch auf der 97er Version funktionieren.

Ich habe eine Verschachtelte Wennfunktion

=WENN(WOCHENTAG(B37;2)=1;Eingabebereich!$C$10;WENN(WOCHENTAG(B37;2)=2;Eingabebereich!$C$11;WENN(WOCHENTAG(B37;2)=3;Eingabebereich!$C$12;WENN(WOCHENTAG(B37;2)=4;Eingabebereich!$C$13;WENN(WOCHENTAG(B37;2)=5;Eingabebereich!$C$14;WENN(WOCHENTAG(B37;2)=6;Eingabebereich!$C$15;WENN(WOCHENTAG(B37;2)=7; Eingabebereich!$C$16)))))))

auf einen SVERWEIS habe ich verzichtet, weil ich eine Tabelle mit Variablen Wochentagen habe. Da hat es leider nicht funktioniert. Stattdessen hab ich nun diese Wennfunktion mit sieben Verschachtelungen (für jeden Wochentag eine), ABER… wenn in B37 kein Wert ("") steht, soll in der Zelle auch kein Wert stehen.

normaler weise füge ich dann =Wenn(B37="";"") vorweg. Da es aber nicht möglich ist, mehr als sieben verschachtelungen zu nutzen stehe ich vor einen kleinem Problem. Man kann das Problem wohl irgendwie mit UND und + umgehen, aber ich bekomme dennoch ständig nur #WERT.

Hat jemand einen Tipp für mich?

Reinhard_fb8cb7 · 12. November 2019 um 13:37

Hallo Sabrina,

=WENN(WOCHENTAG(B37;2)=1;Eingabebereich!$C$10;WENN(WOCHENTAG(B3
7;2)=2;Eingabebereich!$C$11;WENN(WOCHENTAG(B37;2)=3;Eingabebere
ich!$C$12;WENN(WOCHENTAG(B37;2)=4;Eingabebereich!$C$13;WENN(WOC
HENTAG(B37;2)=5;Eingabebereich!$C$14;WENN(WOCHENTAG(B37;2)=6;Ei
ngabebereich!$C$15;WENN(WOCHENTAG(B37;2)=7;
Eingabebereich!$C$16)))))))

spontan und ungetestet aus meinem Bäuchlein :
=Indirekt(„Eingabebereich!$C$“ & 9+WOCHENTAG(B37;2))

PS: hast du XL 97? Ich habe und knnte für dich testen,
(beispiel-) Mappe hochladen

auf einen SVERWEIS habe ich verzichtet, weil ich eine Tabelle
mit Variablen Wochentagen habe. Da hat es leider nicht
funktioniert.

Ohne mehr Infos oder Mappe kann ich damit nix anfangen.
Oder du zeigst zumindest mal die SVerweis-Formeln die nicht klappten.

Stattdessen hab ich nun diese Wennfunktion mit
sieben Verschachtelungen (für jeden Wochentag eine), ABER…
wenn in B37 kein Wert ("") steht, soll in der Zelle auch kein
Wert stehen.

Das ist kein Akt, schreib halt
=Wenn(B37="";"",meine Formel)

normaler weise füge ich dann =Wenn(B37="";"") vorweg. Da es
aber nicht möglich ist, mehr als sieben verschachtelungen zu
nutzen stehe ich vor einen kleinem Problem.

hat sich wohl erledigt.

Man kann das
Problem wohl irgendwie mit UND und + umgehen, aber ich bekomme
dennoch ständig nur #WERT.

Man kann vieles. Z.B. Anstatt =Indirekt() ginge wohl auch eine Lösung
mit =Wahl()

Und „#WERT“ hilft mir nix wenn ich die Formel nicht sehe und ggfs.
die Tabelle.
Zu „UND“ fällt mir grad nix ein, kann sein daß es da auch geht.
Mit + (oder &amp:wink: wird’s auch gehen. Dann könntest du WENNs verbraten
bis die max. Formellänge mit 1023 Bytes erreicht ist.

oder & Benutzung hängt davon ab welche Art von Werten in den
entsprechenden Zellen steht, Text oder Zahl.
Für Zahl wäre das z.B. so:
=wenn(Prüfung auf 1;Blatt!C10;0) + wenn(Prüfung auf 2;Blatt!C11;0) +…

Um das Ganze kannste dann natürlich noch ein Wenn() legen falls
die Prüfzelle leer ist, keine Zahl o.ä.

Frag nach wenn was unklar blieb.

Gruß
Reinhard

Alex_Winter · 12. November 2019 um 13:37

Hallo Sabrina,

=WENN(WOCHENTAG(B37;2)=1;Eingabebereich!$C$10;WENN(WOCHENTAG(B3
7;2)=2;Eingabebereich!$C$11;WENN(WOCHENTAG(B37;2)=3;Eingabebere
ich!$C$12;WENN(WOCHENTAG(B37;2)=4;Eingabebereich!$C$13;WENN(WOC
HENTAG(B37;2)=5;Eingabebereich!$C$14;WENN(WOCHENTAG(B37;2)=6;Ei
ngabebereich!$C$15;WENN(WOCHENTAG(B37;2)=7;
Eingabebereich!$C$16)))))))

auf einen SVERWEIS habe ich verzichtet, weil ich eine Tabelle
mit Variablen Wochentagen habe. Da hat es leider nicht
funktioniert. Stattdessen hab ich nun diese Wennfunktion mit
sieben Verschachtelungen (für jeden Wochentag eine), ABER…
wenn in B37 kein Wert ("") steht, soll in der Zelle auch kein
Wert stehen.

Der SVerweis würde sich da auch anbieten, aber dann müsstest du die Zahlen von 1-7 in eine Spalte schreiben, damit du sie als Kriterium nutzen könntest.
=SVERWEIS(WOCHENTAG(B37;2);Eingabebereich!B10:C16;2;FALSCH)

Nun zu deiner Wenn-Formel. Ich habe sie etwas verändert:

=WENN(ISTLEER(B37);"";WENN(WOCHENTAG(B37;2)=1;Eingabebereich!$C$10;WENN(WOCHENTAG(B37;2)=2;Eingabebereich!$C$11;WENN(WOCHENTAG(B37;2)=3;Eingabebereich!$C$12;WENN(WOCHENTAG(B37;2)=4;Eingabebereich!$C$13;WENN(WOCHENTAG(B37;2)=5;Eingabebereich!$C$14;WENN(WOCHENTAG(B37;2)=6;Eingabebereich!$C$15;Eingabebereich!$C$16)))))))

Bei dieser Formel prüfst du ZUERST B37 auf die leere Zelle ab. Dann kommen die Wochentagsabfragen bis 6 und das letzte Sonst-Argument ist die Zahl für den 7. Wochentag. Wenn die Zelle nicht leer ist und auch nicht 1 - 6 beinhaltet, muss automatisch 7 drinstehen. Daher brauchst du da keine weitere Wenn-Abfrage mehr für den 7. Wochentag. Wenn du noch Fragen dazu hast, bitte melde dich.

Gruß Alex

abgemeldet5 · 12. November 2019 um 13:37

Hallo Sabrina,
die Funktion Wochentag gibt eine Zahl zwischen 1 und 7 wieder, ideal und dieses Ergebnis als Index in WAHL() einzubauen:

Beispiel incl. Prüfung auf 0

=WENN(B370;WAHL(WOCHENTAG(B37;2);Eingabebereich!$C$10;Eingabebereich!$C$11;Eingabebereich!$C$12;Eingabebereich!$C$13;Eingabebereich!$C$14;Eingabebereich!$C$15;Eingabebereich!$C$16);"")

Alternative in deinem Fall ganz ohne wenn():
die Funktion indirekt:

=WENN(B370;INDIREKT(„Eingabebereich!c“&9+WOCHENTAG(B37;2));"")

Gruß Holger

Diether_2c2c7e · 12. November 2019 um 13:38

Hallo Sabrina,

probier mal Folgendes:

=WENN(WOCHENTAG(B37;2)=1;Eingabebereich!$C$10;"")&
WENN(WOCHENTAG(B37;2)=2;Eingabebereich!$C$11;"")&
WENN(WOCHENTAG(B37;2)=3;Eingabebereich!$C$12;"")&
WENN(WOCHENTAG(B37;2)=4;Eingabebereich!$C$13;"")&
WENN(WOCHENTAG(B37;2)=5;Eingabebereich!$C$14;"")&
WENN(WOCHENTAG(B37;2)=6;Eingabebereich!$C$15;"")&
WENN(WOCHENTAG(B37;2)=7;Eingabebereich!$C$16;"")

beziehungsweise

=WENN(WOCHENTAG(B37;2)=1;Eingabebereich!$C$10)+
WENN(WOCHENTAG(B37;2)=2;Eingabebereich!$C$11)+
WENN(WOCHENTAG(B37;2)=3;Eingabebereich!$C$12)+
WENN(WOCHENTAG(B37;2)=4;Eingabebereich!$C$13)+
WENN(WOCHENTAG(B37;2)=5;Eingabebereich!$C$14)+
WENN(WOCHENTAG(B37;2)=6;Eingabebereich!$C$15)+
WENN(WOCHENTAG(B37;2)=7;Eingabebereich!$C$16)

Gruß
Diether

Claude_G · 12. November 2019 um 13:38

Hallo Dieter,
warst etwas schneller als ich. Hatte ich mal so gemacht weil ich das im Netz gelesen habe. Von wegen nur 7!
Gruß
Ratatouille

Reinhard_fb8cb7 · 12. November 2019 um 13:38

Von wegen nur 7!

Hallo Ratatouille,

wie meinst du das nun? Das ist schon ernstgemeint bei verschachtelten WENNs.
Zumindest in einigen Versionen. Ansonsten kann man WENN so oft
benutzen wie man will bis zur max. Formellänge.

Gruß
Reinhard